#define PERIOD 259200       // период работы в секундах (пример: 60*60*24*3 = 259200 - три дня!)
#define WORK 150            // время работы в секундах
/////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
#define MOS 1               //выход на мосфет
#define sensorPin 2       // выход на датчик уровня
uint32_t  mainTimer, myTimer;
boolean   state = false;
#include <avr/wdt.h>
#include <avr/sleep.h>
#include <avr/interrupt.h>
#define adc_disable() (ADCSRA &= ~(1<<ADEN))     // disable ADC (before power-off)
#define adc_enable()  (A00DCSRA |=  (1<<ADEN))   // re-enable ADC

void setup() {
  // все пины как входы, экономия энергии
  for (byte i = 0; i < 6; i++) {
    pinMode(i, INPUT);
  }
  adc_disable();                       // отключить АЦП (экономия энергии)
  wdt_reset();                         // инициализация ватчдога
  wdt_enable(WDTO_1S);                 // разрешаем ватчдог // 15MS, 30MS, 60MS, 120MS, 250MS, 500MS, 1S, 2S, 4S, 8S
  WDTCR |= _BV(WDIE);                  // разрешаем прерывания по ватчдогу. Иначе будет резет.
  sei();                               // разрешаем прерывания
  set_sleep_mode(SLEEP_MODE_PWR_DOWN); // максимальный сон
}

void loop() {
  mainTimer++;
       
  if (!state) {                                                                                // если помпа не включена
    if ((long)mainTimer - myTimer > PERIOD) {                                                  // таймер периода
      myTimer = mainTimer;                         
      state = true;                                 
      if (digitalRead(sensorPin) == HIGH) {
      pinMode(MOS, OUTPUT);                         
      digitalWrite(MOS, HIGH);                     
      }
    }
  } else {                                                                                    // если помпа включена
    if (((long)mainTimer - myTimer > WORK) || (digitalRead(sensorPin) != HIGH)) {             // таймер времени работы
      myTimer = mainTimer;                         
      state = false;
      digitalWrite(MOS, LOW);                     
      pinMode(MOS, INPUT);                                                                    //(экономия энергии)
      }
    }
  sleep_enable();                                                                             // разрешаем сон
  sleep_cpu();                                                                                // спать!
}

ISR (WDT_vect) {
  WDTCR |= _BV(WDIE);                                                                         // разрешаем прерывания по ватчдогу. Иначе будет реcет.
}